How to install a SRCDS

Overview

What is a SRCDS

SRCDS stands for Source Dedicated Server. This is a free stand-alone server program created by Valve. Unlike other type of servers, SRCDS does not require steam or even a copy of Half-Life:2 to install. When installing a SRCDS, the update tool will download all the required files for the server of your choice. Since SRCDS is for a Dedicated Server, you can not play on the same computer that your Dedicated Server is running on. To play and host on the same computer, create a listen server from in-game.

What will does this guild do?

This guide will walk you through how to do a full install of SRCDS with Fortress Forever. This will also explain what you are doing so you can learn more about SRCDS.

How do I make SRCDS work with Fortress Forever

Since SRCDS is made to work with first-party mods (those created by Valve), the Fortress Forever server needs to add to SRCDS. This is done by installing a Half-Life:2 Death Match SRCDS and then adding the FortressForever server to the root. This will all be explained below.

Required Tools

The following tools are required:

• HLDSUpdatetool
• Fortress Forever Server
• 7-Zip/WinZip/WinRar/Ect.

EXPAND THIS!

Walk Through

HLDSUpdatetool

To start off, you need to download HLDSUpdatetool installer. This can be downloaded directly from steam here. Once downloaded, double click on the installer and install it to c:\hldsupdatetool. This will make it easy to find it you ever need it again.

HL2MP Install

First we need to find out way over to the installer. Start by opening a command line. This can be done by going to Start --> Run and then typing cmd. There are a few things you want to do. First you want to move to your C drive. Then create a folder for your server. Then move into your installer folder. Use the following commands:

cd c:\
mkdir ff-server
cd c:\hldsupdatetool

Now that you are in the hldsupdatetool folder, run this command to install HL2MP

hldsupdatetool.exe -command update -game hl2dm -dir C:\ff-server

You should see tons of text scroll by as the correct files are downloaded directly from the steam servers to your server. Congrates! You have installed a HL2MP server!

FF Server Install

Download the Fortress Forever 2.1 FULL (Windows Only) [SERVER]. This can be downloaded here.

Now unzip the whole file to C:\ff-server.

Starting Your FF Server

To make your life easier, here is a windows batch script to automatically run your server. It will also automatically re-start the server if it gets sent a quit or exit command. Create a new file in notepad and save it as "SRCDS Guardian 2.bat". Make sure there is NOT a .txt at the end or the script will not run.

::=======================::
::  SRCDS Guardian 2.0   ::
::         Mooga         ::
::       srcds.com       ::
::=======================::

::=========================================================::
:: Thanks To Black-Sky & Drocona for making SRCDS Guardian ::
:: This script is open source.  Feel free to edit at will. ::
::                                                         ::
:: This script was writen for the use of the srcds.com     ::
:: online community.  If you are interested in running a   ::
:: Source Dedicated Server or need help, drop by our       ::
:: forums at... http://forums.srcds.com                    ::
::=========================================================::



:: This will keep the window clean and easy to read
@echo off

::=======================::
::  SET YOUR VARIABLES!  ::
::=======================::

::=======================::
::  Window and Log name  ::
::  Replace "My Server"  ::
::=======================::
set servername="My FF Server"

::=======================::
::   Your start command  ::
::=======================::
set runcmd=C:\ff-server\srcds.exe -console -game fortressforever -maxplayers 22 +fps_max 200 -port 27015 +map ff_2fort -tickrate 66

:: Sets the title of the window
title SRCDS Guardian 2.0   %servername%


:: Clears the window incase there is anything there
cls


:: Prints to the window what we are doing
echo SRCDS Guardian 2.0 has been started!
echo.
echo **************************************************************************
echo To close the server, close this windows and type exit in the server window
echo **************************************************************************
echo.
echo.

>> %servername%_Guardian.log echo.
>> %servername%_Guardian.log echo (%date%)(%time%) SRCDS Guardian 2.0 has been started!

echo (%date%)(%time%) %servername% is now starting...
>> %servername%_Guardian.log echo (%date%)(%time%) %servername% is now starting...

:: This is a return point in case the server crashes or is closed
:restart

echo (%date%)(%time%) %servername% is now online
>> %servername%_Guardian.log echo (%date%)(%time%) %servername% is now online

echo Watching %servername% for crashes...
>> %servername%_Guardian.log echo (%date%)(%time%) Watching %servername% for crashes...

::Start the actual server
start /wait %runcmd%

echo (%date%)(%time%) Crash or Close detected!
>> %servername%_Guardian.log echo (%date%)(%time%) Crash or Close detected!

echo (%date%)(%time%) %servername% is now restarting...
>> %servername%_Guardian.log echo (%date%)(%time%) %servername% is now restarting...

::Server crashed or closed, so we point it to the return point to start the server again
goto restart